• Options
• Login
• Register
• Desktop Style
• Accelerated Mobile Pages Theme

How to close all AHK scripts without killing Quick Access Popup process?

• Index

  • Jean Lalonde Support Forum
  • QUICK ACCESS POPUP FORUM
  • QAP SUPPORT
  • How to close all AHK scripts without killing Quick Access Popup process?
• How to close all AHK scripts without killing Quick Access Popup process?

• How to close all AHK scripts without killing Quick Access Popup process?

  Popleft > 2025-08-04 14:28

  I am a lot into using scripts. But as I am not a programmer but merely a tweaker and thus sometimes manage to execute some a never ending loop / re-execution - and thus I need to have efficient means to close all wrongly working scripts with just a click.
  
  I already have two solutions:
  
  A] A panic button in form of BAT file pinned at the beginning of always visible Taskbar of Windows. It has [among other commands] these lines:
  
  

  Code:

  taskkill /t /f /im AutoHotkey.exe > nul 2>&1
taskkill /t /f /im AutoHotkeyU64.exe > nul 2>&1
taskkill /t /f /im AutoHotkeyUX.exe > nul 2>&1
taskkill /t /f /im InternalAHK.exe > nul 2>&1

taskkill /t /f /im AutoHotkey > nul 2>&1

  
  
  B] A kill-switch just for AHK scripts that has a form of an icon on a customizable Toolbar of my file-manger. All of its code is this:
  
  

  Code:

  #Requires AutoHotkey v1.1.33

DetectHiddenWindows On
WinGet ahk, List, ahk_class AutoHotkey

Loop % ahk
If (ahk%A_Index% != A_ScriptHwnd)
WinClose % "ahk_id" ahk%A_Index%

ExitApp

  
  
  And here is the weird issue: the option "A" despite being nuclear does not unwantedly close me Quick Access Popup - while the mild option "B" kills also QAP to my despair
  
  The latter, if I am not mistaken, happens because AutoHotkey's built-in tool Window Spy shows in its "Window Title, Class And Process" field for the QAP Tray this:
  

  Quote:ahk_class
  ahk_exe
  ahk_pid

  
  which matches that what the Loop in AHK file is looking for. And for the Customize window of Quick Access Popup it shows
  

  Quote:ahk_class JeanLalonde.ca
  ahk_exe QuickAccessPopup-64-bit.exe
  ahk_pid 20344

  
  
  So, is there a way I can solve this conundrum with scripts i.e. be able to rework the option "B" is such way that it will still kill all AHK processes but with a new exception of QAP [while still also not touching AutoHotkey Help]?
  
  Or will I have to add another instruction to it that will just run QAP i.e. reopen it?

• RE: How to close all AHK scripts without killing Quick Access Popup process?

  Jean Lalonde > 2025-08-04 15:12

  Hi,
  
  > AutoHotkey's built-in tool Window Spy shows in its "Window Title, Class And Process" field for the QAP Tray this:
  > ahk_class
  > ahk_exe
  > ahk_pid
  
  It show nothing because the QAP Tray is not a window.  Window Spy returns info only for windows, like the Customize window.
  
  > So, is there a way I can solve this conundrum with scripts i.e. be able to rework the option "B" is such way that it will still kill all AHK processes but with a new exception of QAP [while still also not touching AutoHotkey Help]?
  
  Try this:
  
  

  Code:

  DetectHiddenWindows On
WinGet, ahk, List, ahk_class AutoHotkey

Loop % ahk
{
    WinGet, OutputVar, ProcessName, % "ahk_id " . ahk%A_Index%
    If (ahk%A_Index% != A_ScriptHwnd) and (OutputVar != "QuickAccessPopup.exe")
        WinClose % "ahk_id" ahk%A_Index%
}

ExitApp

  
  If you have other AHK related questions, I'd prefer if you post them on the AHK Forum. Let me know if you do and I'll be happy to reply if I can help.

• RE: How to close all AHK scripts without killing Quick Access Popup process?

  Popleft > 2025-08-05 14:21

  Unfortunately this code still closes my QAP

• RE: How to close all AHK scripts without killing Quick Access Popup process?

  Xavier > 2025-08-08 00:38

  @popleft
  
  I have a similar oh s*it button in my script. It's alike ur 1st emaple thou set up a little different. it doesn't kill qap on me.
  
  I'm way from my computer for a couple days so I can share the snippet this week

• RE: How to close all AHK scripts without killing Quick Access Popup process?

  Xavier > 2025-08-09 21:07

  Try this snippet in your script. I've been using this for over a year and works great. 
  
  I have a couple side scripts that running as admin so my main needs to be elevated before trying to kill them. hence the iniwrite, it's a variable layout as a work around so my main script isn't  always starting as admin. there's also another If ( RestartAfterKill ) that restarts my other 4 side scripts that would have been killed by this label, once I restart my main script after kill everything.
  
  I use this often as I'm playing and it doesn't not kill QAP for me.
  
  

  Code:

  ;; above first return, in auto-exe
iniread, KillAHK, Logging, KillAHK, 0
if (KillAHK)
{
     tooltip x AHKs x is `n Killing It...
     iniwrite, 0, %inifile%, Logging, KillAHK
     sleep 150
     goto KillAHK
}
if ( RestartAfterKill )
{
     RunScriptsonBOOT() ;; define which side scripst you want to run on a fresh main script run here (if any)
     IniWrite, 0, %inifile%, Logging, RestartAfterKill
}
;; Return ; First Return
;-------------------------
;; below auto-exe
^#!End:: ;; Kill all AHK Scripts running in background
KillAHK:
If !A_IsAdmin
{
     iniwrite, 1, %inifile%, Logging, RestartAfterKill
     sleep 100
     Run *RunAs "%A_ScriptFullPath%"
}
run, cmd.exe /c "taskkill /f /im AutoHotkeyU64.exe"
sleep 100
run, cmd.exe /c "taskkill /f /im autohotkey.exe"
sleep 100
Run, cmd.exe /c "taskkill /f /im autohotkeyu32.exe"
sleep 100
run, cmd.exe /c "taskkill /f /im autohotkeyux.exe"
sleep 100
run, cmd.exe /c "taskkill /f /im autohotkey64.exe"
sleep 100
run, cmd.exe /c "taskkill /f /im autohotkey64_UIA.exe"
sleep 100
run, cmd.exe /c "taskkill /f /im AutoHotkeyU64_UIA.exe"
        ;; I run all my scripts with UI Access, found it best to keep this one at the bottom of this kill list.
sleep 100
Exitapp
return
return

• RE: How to close all AHK scripts without killing Quick Access Popup process?

  Popleft > 2025-08-11 16:17

  (2025-08-09 21:07)Xavier Wrote: Try this snippet in your script. 
  [...]

  
  At first I stripped down your script to bare bones:
  
  

  Code:

  Run, cmd.exe /c taskkill /f /im AutoHotkeyU64.exe,, Hide
Run, cmd.exe /c taskkill /f /im autohotkey.exe,, Hide
Run, cmd.exe /c taskkill /f /im autohotkeyu32.exe,, Hide
Run, cmd.exe /c taskkill /f /im autohotkeyux.exe,, Hide
Run, cmd.exe /c taskkill /f /im autohotkey64.exe,, Hide
Run, cmd.exe /c taskkill /f /im autohotkey64_UIA.exe,, Hide
Run, cmd.exe /c taskkill /f /im AutoHotkeyU64_UIA.exe,, Hide

Run, "%A_ScriptDir%\the script i need to automatically re-run.ahk"

ExitApp

  
  But then I realized that not wanting to use an additional external file would create a Catch-22 situation [i.e. the >>Run<< command would not be executed because also that script would close itself as part of the killing sweep it performs]
  
  But I think I have managed to go around it by using the WMI identification method [the descriptive names of variables and comments in below code explain its inner-workings]:
  
  

  Code:

  /*
This scripts closes all running AHK scripts - except this one. It does this by identifying them by the EXE that runs them i.e. it does not identify them by their Windows class nor the title of their window
It does not close [on purpose]:
● AutoHotkey Help [because that process uses the hh.EXE file of Windows]
● Quick Access Popup [because that process has its own EXE]
● SciTE4AutoHotkey [because that process has its own EXE]
*/
; #SingleInstance  ; Do not use this - so that the user will have a greater chance to end a whack-a-mole situation by being able to manually execute this panic button multiple times
WMI_query := "Select * from Win32_Process where "  ; This looks in Windows Management Instrumentation list for all running processes matching defined AutoHotkey executable variants
    . "Name='AutoHotkey.exe' "   ; V1 / V2 main runner
    . "or Name='AutoHotkey32.exe' "   ; V2 32-bit
    . "or Name='AutoHotkey32_UIA.exe' "   ; V2 32-bit User Interface Automation build
    . "or Name='AutoHotkey64.exe' "   ; V2 64-bit
    . "or Name='AutoHotkey64_UIA.exe' "   ; V2 64-bit User Interface Automation build
    . "or Name='AutoHotkeyA32.exe' "   ; V1 32-bit ANSI
    . "or Name='AutoHotkeyU32.exe' "   ; V1 32-bit Unicode
    . "or Name='AutoHotkeyU32_UIA.exe' "   ; V1 32-bit User Interface Automation build
    . "or Name='AutoHotkeyU64.exe' "   ; V1 64-bit Unicode
    . "or Name='AutoHotkeyU64_UIA.exe' "   ; V1 64-bit User Interface Automation build
    . "or Name='AutoHotkeyUX.exe' "   ; V1 experimental build
    . "or Name='InternalAHK.exe'"   ; SciTE4AutoHotkey editor internal runner
WMI_COM_item := ComObjGet("winmgmts:")   ; This runs system-level queries and fetches information about running processes
AHK_processes_list := WMI_COM_item.ExecQuery(WMI_query)   ; This returns a collection of process objects matching the query criteria
this_file_ID := DllCall("GetCurrentProcessId")   ; This gets the PID of this file in order to prevent its closure - so that this script will remain being able to automatically execute pre-defined commands after performing the task of killing all others scripts
for each_process in AHK_processes_list   ; This loop through each found AutoHotkey process and kills it - if it is not this file
{
    process_an_ID := each_process.ProcessId
    if (process_an_ID != this_file_ID)
    Process, Close, %process_an_ID%
}
; The below repeats the above task in order to deal with any [re]executions of AHK scripts that might happen in middle of initial kiliing procedure
max_retries_number := 3
retry_delay_in_miliseconds := 555
Loop % max_retries_number
{
    Sleep, %retry_delay_in_miliseconds%
    new_AHK_processes := WMI_COM_item.ExecQuery(WMI_query)
    found_new := false
    for proc in new_AHK_processes
    {
        if (proc.ProcessId != this_file_ID)
        {
            Process, Close, % proc.ProcessId
            found_new := true
        }
    }
    if (!found_new)
        break
}
Run, "%A_ScriptDir%\the script i need to automatically re-run.ahk"   ; This re-executes necessary script
ExitApp

  
  I have tested the above script and I think my problem became solved
  

  ---

  ---

  (2025-08-11 16:17)Popleft Wrote: [...]
  I have tested the above script and I think my problem became solved

  
  Although this script could use two upgrades:
  
  ● Logging to a TXT: a simple >>FileAppend<< for finding possible rogue / hidden scripts
  ● Dynamic EXE list: automatic scanning for all new EXE files of future AutoHotkey releases and / or experimental builds
  
  But for now I am satisfied with how it seems to work

• RE: How to close all AHK scripts without killing Quick Access Popup process?

  Popleft > 2025-08-12 08:32

  (2025-08-11 16:17)Popleft Wrote: Although this script could use
  [...]

  
  Also exlusion of TillaGoTo For SciTE4AutoHotkey script by the TheGood - i.e. upgrade of the
  
  

  Code:

  WMI_query := "Select * from Win32_Process where " 

  
  list with a line of
  
  

  Code:

      . "and not CommandLine like '%TillaGoto.ahk%'"  ; [exclude]

  
  
  And on a side note:
  
  

  (2025-08-04 14:28)Popleft Wrote: [...]
  A] A panic button in form of BAT file pinned at the beginning of always visible Taskbar of Windows
  [...]

  
  could be reworked entirely to
  
  

  Code:

  :: In order to work this BAT file must be executed As Administrator

@echo off

setlocal enabledelayedexpansion

set "AHK_executables=AutoHotkey.exe AutoHotkey32.exe AutoHotkey32_UIA.exe AutoHotkey64.exe AutoHotkey64_UIA.exe AutoHotkeyA32.exe AutoHotkeyU32.exe AutoHotkeyU32_UIA.exe AutoHotkeyU64.exe AutoHotkeyU64_UIA.exe AutoHotkeyUX.exe InternalAHK.exe"

for %%E in (%AHK_executables%) do (
    for /f "skip=1 delims=" %%L in ('wmic process where "name='%%E'" get CommandLine^,ProcessId 2^>nul') do (
        set "line_currently_processed=%%L"

        if defined line_currently_processed (
            for /f "tokens=* delims=" %%a in ("!line_currently_processed!") do set "line_currently_processed=%%a"
            echo !line_currently_processed! | findstr /i "ProcessId" >nul && (
            ) || (
                echo !line_currently_processed! | findstr /i /c:"TillaGoTo.ahk" >nul
                if errorlevel 1 (
                    for /f "tokens=* delims= " %%p in ("!line_currently_processed!") do (
                        for %%z in (!line_currently_processed!) do set "process_ID=%%z"
                        taskkill /f /pid !process_ID! >nul 2>&1
                    )
                )
            )
        )
    )
)

endlocal

  
  But if such exclusion is activated both in BAT and AHK killer scripts, then this will create [once opened / executed] a never closing point of entry for a potential malware and / or glitches. And so I think it is better to leave that accompanying BAT without exception for any AHK script
• Next Oldest Next Newest