Options
Trigger the menu to appear with a double right click of the mouse
- Trigger the menu to appear with a double right click of the mouse
-
Trigger the menu to appear with a double right click of the mouse
Jean Lalonde > 2025-07-29 09:27
Suggestion received by email. -
RE: Trigger the menu to appear with a double right click of the mouse
Xavier > 2025-08-01 04:10
I've been using a global double right click hotkey to show my own menu for about year.
here's a snippet (;; with comments) that I hope you can find helpful in adapting to qap
this was a bit tricky to work out as the 1st right click will always try to trigger the active apps own context menu, resulting in two right click menus showing on screen, with one of them frozen below the other. I found adding small sleeps around sending {alt down}{alt up} will prevent this from happing. for my own script the sleeps work perfectly 97% of time.
Code:~RButton:: ;; double right click to show ECLM
doublerightclick:
if (A_PriorHotkey != "~RButton" or A_TimeSincePriorHotkey > 300)
{
KeyWait, rbutton, u ;; Too much time between presses, so this isn't a double-press.
Return
}
else
{
sleep 40
;; ↑↑↑ this small pause might not be necessary per-say, but I found it helpful to for the underlying program to see the first right-click which triggers a native context menu in most apps. without this pause I would be getting both right click menus showing over top of each other about half the time. harmless but annoying cause you have to click around to close both menus then double-right click again.
SendInput, {alt down}{alt up}
;; ↑↑↑ this clears\cancels the native from the 1st right-click. there likely could be another way overriding this using a windows "OnMessage()" that I'm not aware of. I've found it reliably enough for my own menu. not all apps respond to sending alt to close a menu, the windows desktop menu is a problematic one to work around.
Gosub CMenu
;; ↑↑↑ build my own menu dynamic menu items
sleep 20
;; ↑↑↑ another tiny pause to make sure the {alt-down-up} has been successfully sent, again found this help so you'd not have 2 competing context menus at once. depending on the app and how fast dynamic menu items are built, on different systems these sleep times may need to be adjusted a bit, took me while to find the sweet spot
menu, c, show
;; ↑↑↑ finally show the menu. ;; in qaps case replace this with..., Run, %QAPm% ShowMenuLaunch
}
Return -
RE: Trigger the menu to appear with a double right click of the mouse
Jean Lalonde > 2025-08-01 09:46
In addition to this context menu issue, integrating this feature inside QAP complex triggers environment is another challenge. But, anyway, thanks for the tip Xavier. -
RE: Trigger the menu to appear with a double right click of the mouse
Jean Lalonde > 2026-02-10 17:26
Hi Xavier.
I'm giving this idea a try using your code. I'm having issues with the context menu sometimes showing on top of the QAP menu.
Question: What is " KeyWait, rbutton, u" doing exactly? According to the AHK doc, U is not an option for KeyWait. -
RE: Trigger the menu to appear with a double right click of the mouse
Xavier > 2026-02-10 23:02
hiya!
#1 lets see, hmm, I'm not quite sure why i have Keywait, {key}, u in here. i thought i had seen in in the ahk help docs but now that I'm looking again at the double tab example KeyWait page ... not seeing there so I'm not sure sure where i picked that up from.
i ended up putting in a macro i made so now it all over my own script. my thought was its waiting up {RButton Up}. even though the syntax isn't listed, i have many double tap keys with that in them and they still work. i will be removing the ", u" from them from here on in.
#2 Yes getting two context menu competing\showing over top of each other is the trick part of this formula to figure out. i've had to use a mixture of sleeps and sendinput, {alt}'s to clear the first menu, than build and show my own. i have had to adjust the sleep timings a few times to get it just right.
this is what's currently running in my script... with some comments
Code:~RButton:: ;; double right click to show ECLM
doublerightclick:
if (A_PriorHotkey != "~rbutton" or A_TimeSincePriorHotkey > 300)
{
KeyWait, rbutton ; Too much time between presses, so this isn't a double-press.
return
}
else
{
sleep 81 ;; wait for active program to see a right click
Sendinput {alt down}{alt up} ; OR ; send {esc} ;; this send alt||esc is ment to clear the active programs context menu, I've found the alt down|up combo to work best, sometimes sending {esc} will GUIEscape windows you don't want to close, etc.
; gosub cmenu ;; building the menu label:
sleep 20 ;; another short pause to make sure the above Send, {alt} has cleared the first context menu
; ShowMUM("c") ;; my own func to show a menu under my pointer. its Menu, C, Show {with mosusegetpos ~ %x%,%y% added}
Run, %qapm% ShowMenuLaunch
}
return
i replaced my own menu with Run, %qapm% ShowMenuLaunch and I'm having issues with it...
i see the first context menu flash, the alt down\up clears it, then QAP builds its self and shows but its getting stuck up unless a menu item clicked to clear it.
I'm typing in my browser window now with qap menu still open from ~RButton:: over the desktop. i can move windows around behind it.
if i try to call it again with this same hotkey it get this error box and the menu remains open
---------------------------
Quick Access Popup Messenger (v1.4)
---------------------------
An error occurred.
Make sure Quick Access Popup is running before using its context menus.
Search for "Messenger" on www.QuickAccessPopup.com for help.
---------------------------
OK
---------------------------
I'm kinda of an AHK amateur, my scripts are fairly simple label and easy function based. i haven't been able figure out how classes and advanced system environment vars such as you do in qap. so I'm not sure what to suggest on why its staying stuck open like this.
![[Image: cxlfkYr.png]](https://i.imgur.com/cxlfkYr.png)
-
RE: Trigger the menu to appear with a double right click of the mouse
N1ck > 2026-02-11 07:50
This script still has the issue with a normal right-click menu popping up, and I would think any script variation that includes the ~ symbol before it like "~RButton", cannot stop that behavior from happening because the symbol makes a hotkey button perform its normal function along with a script action.
Code:~RButton::
PressCount++
SetTimer, DoublePress, -250
Return
DoublePress:
If (PressCount = 2)
{
Send {Alt}
Run, "C:\Program Files\Quick Access Popup\QAPmessenger.exe" ShowMenuNavigate
}
PressCount := 0
Return
A script to perform a double right-click action without a normal right-click menu popping up is technically possible, but there's a trade-off with that script variation, being the normal right-click button's drag functionality will no longer work.
So the above script keeps all the normal right-click button functionality with the trade-off of a quick showing of the normal right-click menu before launching the QAP menu. -
RE: Trigger the menu to appear with a double right click of the mouse
Jean Lalonde > 2026-02-11 09:48
Xavier > QAP builds its self and shows, but it's getting stuck up unless a menu item clicked to clear it.
Thakns for the explanation. About the menu getting stuck, this could be caused by the intermittent Windows issue that I named "Close menu issue". See: https://www.quickaccesspopup.com/what-is...enu-issue/
Xavier > if I try to call it again with this same hotkey it gets this error box and the menu remains open
This is because while the QAP menu is displayed, QAP is waiting for a menu selection from the user. During that time, QAP is inactive and cannot respond to QAPmessenger. QAPmessenger then displays this error message.
N1ck > but there's a trade-off with that script variation, being the normal right-click button's drag functionality will no longer work.
Thank you for this script. It works well. In my first test, right-click drag still works! I tested right-dragging a folder in Explorer. -
RE: Trigger the menu to appear with a double right click of the mouse
Xavier > 2026-02-11 09:57
(2026-02-11 07:50)N1ck Wrote: A script to perform a double right-click action without a normal right-click menu popping up is technically possible, but there's a trade-off with that script variation, being the normal right-click button's drag functionality will no longer work.
yes! it's a tricky key to play with out side of self-built "ahk_class AutoHotkeyGUI"
i also have this in my main script to replace\show my own AHK instead of notepad++'s own context menu
Code:#ifwinactive ahk_class Notepad++
rbutton:: ;; if NP++, replace context menu with ECLM
replacenpppcontext:
if MouseIsOver("ahk_exe notepad++.exe") && (Control = "Scintilla1") || (Control = "Scintilla2") || (Control = "Scintilla3") || (Control = "Scintilla4")
{
KeyWait, RButton, T0.5 ; Wait for the button to be released, with a 500ms delay
gosub cmenu ; Show custom menu
menu, c, show
}
else
sendinput, {rbutton}
return
#ifwinactive
this shows my own menu over the Scintilla controls, and np++'s menus over the tabs, toolbars, etc -
RE: Trigger the menu to appear with a double right click of the mouse
Jean Lalonde > 2026-02-16 17:06
Done in v12.2. See: https://forum.quickaccesspopup.com/showt...p?tid=3153
I took the opportunity to improve the way the Ctrl+Ctrl command is implemented using the "SetTimer, DoublePress" code above. Thanks! -
RE: Trigger the menu to appear with a double right click of the mouse
Xavier > 2026-02-16 19:06
Nice. You had luck getting it open internal without locking? I'll check it out in a bit -
RE: Trigger the menu to appear with a double right click of the mouse
Xavier > 2026-02-17 10:08
very nice! i hope some of y'all find this useful.
and as for it getting stuck open... its not UNLESS i have my own scripts doublerightclick: hotkey running, then the timing in show both get out of line and someone's getting stuck. lol. its all good thou.
Thank you
on a side note for other fun keys. i love this one and use a lot , globally for all my F## keys and inside #ifwinactive's for more customization.
this key has 3 action, a single tap, a double tap, and a hold. the time are adjustable. i have them set kind of low 0.15 th of Second.
i don't expect this to show up in QAP. I'm just sharing it so you or anyone else can play with it if you want to try it out.
there are two bit of code the first is "Live Snippet" i use to create the key and paste it my editor, usually notepad++. the second is an example of how i have a key or two set up in my own script ( this won't run in any else's, just showing it versatility).
the input box will ask which key you want to asign "3 Actions" to. enter a raw keyname eg F1 or Home or NumpadDiv without any formating around it. ill add i usually don't do try to apply these to alpha\numeric keys {A-Z0-9}, its doable but it may messing just typing out sentence.
Code:;---------------------------------------------------------------------------
insert3actionskey:
InputBox, keyname,,Enter the KeyName you want to add 3 actions to...
if errorlevel
return
; backupclipboard()
sleep 100
clipboard := ""
sleep 40
clipboard =
(
$%keyname%:: ;; 3key, COMMENT
; WinGetTitle, winTitle, A
; WinGetClass, winClass, A
KeyWait %keyname%, T0.15
if ErrorLevel ;; %keyname%::Long\Hold Press
{
Return
}
else
{
KeyWait %keyname%, D T0.15
if ErrorLevel ;; %keyname%::One Press
{
SendInput, {%keyname%}
}
else ;; %keyname%::Double Press
{
Return
}
}
KeyWait %keyname%
Return
)
sleep 200
sendinput, ^v
; sleep 300
; restoreclipboard()
sleep 800
return
;---------------------------------------------------------------------------
the live snippet about will output\produce...
Code:$F1:: ;; 3key, COMMENT
; WinGetTitle, winTitle, A
; WinGetClass, winClass, A ;; uncomment these if you want to use certain window attrbs
KeyWait F1, T0.15
if ErrorLevel ;; F1::Long\Hold Press
{
Return
}
else
{
KeyWait F1, D T0.15
if ErrorLevel ;; F1::One Press
{
SendInput, {F1} ;; this sends the original key input. i recommend leaving this. it can be overridden by placing If Winactive("your window") { with a Return } above it
}
else ;; F1::Double Press
{
Return
}
}
KeyWait F1
Return
now fill in what you want to happen inside the 3 sets of brackets... here's my F8 Key, which is short one.
* my f11 key is busy with about 200+ lines of else if {}'s inside of
Code:$F8:: ;; multi key, qap, flow luncher, open
KeyWait F8, T0.15
if ErrorLevel ;; F8::long press
{
gosub QAPLiveMenu ;; open my QAP\IF Menu for the active App
}
else
{
KeyWait F8, D T0.15
if ErrorLevel ;; F8::One Press
{
if WinActive("ahk_exe Typora.exe")
{
sendinput, ^{/}
return
}
if Winactive("ahk_class dopus.lister")
{
run, %dopusrt% /acmd Set VIEWPANE=Toggle
return
}
sendinput, {F8} ;; F8::One Press
}
else ;; F8::Double Press
{
if Winactive("ahk_class dopus.lister")
{
send, ^h
return
}
; sendinput, !{space} ; f8::Double Press, show flow
sendinput, #`` ;; F8::Double Press, show listary menu
}
}
KeyWait F8
return
setting each key up with ifs and else ifs inside the 3 sections makes it easy to keep them all in a single spot\script file. my #Include "\3 Keys.ahk" file is 2500+ lines.
have fun!