Options
Adding Hotstrings directly ?
- Adding Hotstrings directly ?
-
Adding Hotstrings directly ?
AlbatrosXL > 2019-10-02 14:53
Is there a possibility to define a HotKey which opens immediately a QAP-Window to add a hotstring ?
Example:
- I marked a text within an editor (or browser)
- I press WIN+H (Hotkey)
- QAP opens the window which allows me to add a hotstring / snippet text (see window below..).
That would be a next level in improving the speed of work with text-blocks..
Thanks in advance
kind regards
AlbatrosXL
P.S: I thought about writing an AHK-skript which is called if the Hotkey is pressed and then starts the following sequence
* opening QAP
* going to my submenuefolder for Hotstrings
* pressing the Add-button
* selecting Snippet (cursor commands)
* press the continue-button..-
BUT .. this takes a lot of time and is not very stable - as the AHK-Script needs to work with counts of cursor-movements etc... - I marked a text within an editor (or browser)
-
RE: Adding Hotstrings directly ?
Jean Lalonde > 2019-10-02 15:17
(2019-10-02 14:53)AlbatrosXL Wrote: Is there a possibility to define a HotKey which opens immediately a QAP-Window to add a hotstring ?
Good idea. Added to the wishlist:
https://forum.quickaccesspopup.com/showt...hp?tid=269
(2019-10-02 14:53)AlbatrosXL Wrote: P.S: I thought about writing an AHK-skript which is called if the Hotkey is pressed and then starts the following sequence
It would be easier if you build your AHK macro using the keyboard sequence (Send command) instead of the mouse pointer.
The sequence would be something like: Shift+Ctrl+C (with v10, or Shift+Ctrl+S with v9) to open the Customize window (aka Settings in v9), Ctrl+N (Add new favorite), S (keyboard accelerator for Snippet), Enter, Menu name, Tab, Snippet content, Ctrl+Tab (Menu Options tab), 8 Tabs (Change Hotstring button), etc.
AHK macros based on keystrokes are much more reliable.
Jean
PS: I'll move this thread to the Suggestions section. -
RE: Adding Hotstrings directly ?
AlbatrosXL > 2019-10-03 13:03
Hello Jean,thanks a lot for the feedback & proposal !I'll give it a try !I'm looking forward for this improvement in Quick Access PopPup 10
kind
regards
AlbatrosXL -
RE: Adding Hotstrings directly ?
AlbatrosXL > 2019-10-03 17:02
Hello Jean,
I wrote an autohotkey script to realize the proposal.
Unfortuanetly - I wasn't able to bring it up and running.
I managed to call the QAP setting window by sending the hotkeys Shift+Ctr+S. (using QAP 9)
But the next sequence (Ctrl+N) seems not to be received by QAP.
I tried several variants - and none of them are working.
May I ask you to have a short check on my script ?
Thanks in advance
AlbatrosXL
; **************************
; * Quick access for Hotstrings
; *
; * The script opens a Autohotkey input window which
; * aks for hotstring shortcut
; * ask for the hotstring text
; * pressing okay starts the transfer to QAP
; * pressing cancel - stops the procedure
; *
; * features for later editions
; * check clipboard and insert clipboard text into the box
; *
; ** Inputbox for Hotstring-Trigger & Hotstring
Gui, Add, Text,,TxtShortCut ;Text
Gui, Add, Edit, vHotTrigger w400 r1, 123# ;Inputfield for HotStringTrigger
Gui, Add, Text,,Txtstring
Gui, Add, Edit, vHotString w400 r10, Test text ;Example text; later replac. by clipb.
Gui, Add, Button, w100 x10 y220 Default, Ok
Gui, Add, Button, w100 x310 y220 ,Cancel
Gui, Show
return
GuiClose:
Gui, Destroy
ExitApp
ButtonCancel:
Gui, Destroy
ExitApp
ButtonOK:
Gui, Submit
MsgBox ,,YourInput, "%HotTrigger% and %HotString%" ;just for debugging
; Send +^s ; working
; Send ^n ; not working
Send {Shift Down}{Ctrl Down}s{Shift up}{Ctrl Up} ;working
Send {Ctrl Down}n{Ctrl up} ;not working
MsgBox ,, End ;just for debugging
; Send n{Enter} ; send N+Enter (Select snippet + press enter)
; ControlSetText, Edit1, %HotTrigger% ; insert a Name for the Hotstring
; ControlSetText, Edit2, %HotString" ; insert the hotstring into QAP
; Send {Ctrl}{Tab} ; leave the edit2 / text window
; Send {Ctrl}{Tab} ; go to Menu Options
; ControlSend, Button6, {Enter} ; press Button6 = Change Hotstring trigger
; ControlSetText, Edit1, %HotTrigger% ; insert Hotstring value
; end of procedure - to ensure, last check by user
Exit -
RE: Adding Hotstrings directly ?
Jean Lalonde > 2019-10-03 17:07
I forgot to mention that this example was for QAP v10. In QAP v9, this Ctrl+A key adds a new favorite. I suggest that you upgrade to v10 before doing this macro.
Jean -
RE: Adding Hotstrings directly ?
AlbatrosXL > 2019-10-04 13:12
Hello Jean,
the topic Iposted is independent from the QAP-Version.
Nevertheless - I managed to write now a script which can be started by a QAP-Hotkey (assigned to an AHK-script).
The script has a small GUI and works as following:
- Start by a Hotkey fired by QAP (can be defined)
- then it fires a CTRL+C to copy any marked text into the clipboard
- next: opening a GUI which shows
* an input field for a HotString-Trigger
* edit field to change the clipboard content (which has been copied into this field)
* optional: input field for a HotString-Name
- pressing "OK" starts all the sequences to
* bring up the QAP-windows to fill in HotString, HotStringName, HotStringtrigger
- it stops, when all fields are filled in - and remains for a last user-check
The script has currently only one constraint.
A subfolder within the MAIN-Window is needed which is called 'Hotstrings' (Main > Hotstrings)
(For programmers - it could be changed - as this is a variable within the autohotkey script)
kind regards
AlbatrosXL
Attachements: Screenshot of the GUI / AHK-CODE
Code:; **************************
; * Quick access for Hotstrings for QAP 9.x
; * Adaptions for QAP 10.x maybe in rows.marked with !QAP!
; *
; * The script opens a Autohotkey input window which
; * ask for hotstring trigger (mandatory entry)
; * ask for a shortname (not mandatory: if empty, then = Hottrigger
; * ask for the hotstring text (mandatory)
; If clipboard content exist - then the clipboard content is taken
;
; * pressing okay starts the transfer to QAP
; * pressing cancel - stops the procedure
; *
; * Additional informations
; * Script needs in QAP a subfolder called Hotstrings
; * the subfolder is below the Main-folder (Main > Hotstrings)
; * !! Take Care of the writing !!
; * Subfolder can have a different name, then change the value
; * below at SubMenuHotstring
; -------------------------------
; * Global variables
; V01: initial version
; V02: improvement on speed - replacement of sleeps..
SubMenuHotstring = Main > Hotstrings ;String for selection of Favorite parent menu
;where the hotstrings are stored
PrgError = 0 ;prg-variable Error = 0 -> no error detected
HotTrigger := ""
ShortName := ""
HotString := ""
ErrorSection = "Main"
; -------------------------------
;press Ctrl+C to copy marked text into clipboard
Send, {Ctrl Down}c{Ctrl up}
ShowGui:
; -------------------------------
; ** GUI for Enter of Hotstring-Trigger & Hotstring
Gui, Add, Text, x10 y20 ,TxtShortCut (mandatory) ;Text
Gui, Add, Text, x250 y20 ,Short name
Gui, Add, Edit, vHotTrigger x10 y40 w200 r1 ;Inputfield for HotStringTrigger
Gui, Add, Edit, vShortName x250 y40 w200 r1
Gui, Add, Text, x10 y80, Txtstring (mandatory)
Gui, Add, Edit, vHotString x10 y100 w450 r10, %Clipboard% ;Example text; later replac. by clipb.
Gui, Add, Button, w100 x10 y250 Default, Ok
Gui, Add, Button, w100 x350 y250 ,Cancel
Gui, Show, AutoSize, Quick-Hotkey-Inserten for QAP
return
;
; -------------------------------
; PROGRAMM-FLOW STARTS HERE FOR OKAY-SELECTION------
ButtonOK: ;Button okay pressed
; -------------------------------
Gui, Submit ;store values of edit fields in variables
gosub, CheckEntryValues ;do a plausability check on entry fields
if PrgError = 1
goto ShowGui
gosub, Call_QAP_SettingWindow ;open QAP and select SubMenu for Hotstrings
gosub, Enter_HotStringValues_Into_QAP ;put values into QAP
Gui, Destroy ;release RAM
ExitApp
; ---- PRG - END -----------------
; #########################################
; SubRoutines
; -------------------------------
GuiClose: ;Close or Cancel button pressed
; -------------------------------
Gui, Destroy ;close window
ExitApp ;exit
; -------------------------------
ButtonCancel:
; -------------------------------
Gui, Destroy
ExitApp
; -------------------------------
ErrorOccured:
; -------------------------------
MsgBox, 48, Error, An Error occured in section %ErrorSection%
Gui, Destroy
ExitApp
; -------------------------------
CheckEntryValues:
; -------------------------------
; Do a Plausability check, no empty fields are allowed
PrgError = 0
If (HotTrigger = "" ) ;HotTrigger value exist ?
PrgError = 1 ;no -> Error & Exit
If (HotString = "" ) ;HotString exist ?
PrgError = 1 ;no -> Error & Exit
If (ShortName = "") ;if no ShortName is entered, then
ShortName := HotTrigger ;use the value of the HotTrigger
If PrgError = 1
{
MsgBox, 16, Warning, No empty fields allowed`nPlease try again
}
Gui, Destroy
return
; -------------------------------
Call_QAP_SettingWindow:
; -------------------------------
; *** Open QAP-Setting window by Shift+Ctr+S
; *** select the submenu where the Hotstrings are stored
; *** press then the ADD-Button to open the Add Fav. window
; *** select within the Add Fav-window: Snippet & press Continue
; *** -> Hotstring entry window is open
; *** end
ErrorSection := "Call_QAP_SettingWindow - Main"
Send, {Shift Down}{Ctrl Down}S{Shift up}{Ctrl up} ;!QAP! opening QAP-Setting window
; *** press the Add-Button and select Snippet and continue
WinWaitActive, ahk_class JeanLalonde.ca,,2 ;!QAP!
If ErrorLevel = 0 ;if Win exist
{
winactivate ;activates the SettingWindow
Control, ChooseString, %SubMenuHotstring%, ComboBox1 ;!QAP! select the menu where to store the hotstring
ControlClick, static2 ;!QAP! click on the ADD-Button
}
else
goto, ErrorOccured
WinWaitActive, Add Favorite Type - Quick Access Popup,,2 ;!QAP! - if title changed
If ErrorLevel = 0
{
WinActivate
ControlClick, Button8 ;!QAP! select the snippet-radiobutton
ControlClick, Button14 ;!QAP! press Continue
}
else ;Window not appeared - so inform user and close the script
{
ErrorSection := "Call_QAP_SettingWindow - Add Favorite"
goto, ErrorOccured
}
return
; -------------------------------
Enter_HotStringValues_Into_QAP:
; -------------------------------
; *** Snippet-Window is open and add the values to the entry-fields
ErrorSection := "Enter_HotStringValues_Into_QAP: Add Favorite"
WinWaitActive, Add Favorite: Snippet,,2 ;!QAP! check if Snippet entry window exist
If ErrorLevel = 0
{
ControlSetText, Edit1, %ShortName% ;!QAP! enter ShortName for Hotstring
ControlSetText, Edit2, %Hotstring% ;!QAP! enter HotString
ControlFocus, SysTabControl321, Add Favorite: Snippet ;!QAP! init TAB-Change to Menu options
ControlSend, SysTabControl321, {Ctrl Down}{Tab}{Ctrl Up},
ControlClick, Button6 ;!QAP! Press Change button for Hotstring-Trigger
}
else
goto, ErrorOccured
ErrorSection := "Enter_HotStringValues_Into_QAP: Change Hotstring"
WinWaitActive, Change hotstring - Quick,,2 ;!QAP! check if HotTrigger-Window is open
If ErrorLevel = 0
{
ControlSetText,Edit1, %HotTrigger% ;!QAP! enter Hottrigger string
ControlClick, Button5 ;!QAP! press okay button
}
else
goto, ErrorOccured
return -
RE: Adding Hotstrings directly ?
Jean Lalonde > 2019-10-04 13:33
Great :-) I'll test it.
Maybe you would like to share it on AutoHotkey Script forum :-)
Thanks for sharing,
Jean -
RE: Adding Hotstrings directly ?
Jean Lalonde > 2019-10-04 13:48
I looked at your script. Well done. But as it is, it could not run on v10. I did not make it run yet but I saw that at least these changes would be required for v10:
Line 130: In QAP v10, the default shortcut for Customize window (aka Settings) for new installations is now Shift+Ctrl+C. (it remains Shift+Ctrl+S if you upgraded from a previous version). And users could change it afterward, of course.
Lines 146/147/180: button control numbers changed in the new Customize window.
I don't say you need to do it but other users who would like to use it would have to change these lines. -
RE: Adding Hotstrings directly ?
AlbatrosXL > 2019-10-04 13:53
(2019-10-04 13:48)Jean Lalonde Wrote: I looked at your script. Well done. But as it is, it could not run on v10. I did not make it run yet but I saw that at least these changes would be required for v10:
Line 130: In QAP v10, the default shortcut for Customize window (aka Settings) for new installations is now Shift+Ctrl+C. (it remains Shift+Ctrl+S if you upgraded from a previous version). And users could change it afterward, of course.
Lines 146/147/180: button control numbers changed in the new Customize window.
I don't say you need to do it but other users who would like to use it would have to change these lines.
Hi Jean,
I could do it.
So far I understood - the V10 is still in a Beta-phase.
I thought I can change - if it is close to stable with regard to changes on QAP-internal Hotkeys and Menustructures.
Pls. give me a hint - and I will start to adapt
-
RE: Adding Hotstrings directly ?
Jean Lalonde > 2019-10-04 13:58
QAP v10 is now in "soft-launch", not beta anymore. It means that it is public but alerts are not sent to the "check for update" when I release a new version. Instead, you could subscribe to this thread: https://forum.quickaccesspopup.com/showt...hp?tid=260
I would say it is close to stable. But there are still bugs to be found, especially when combining various options together that would not be all tested by beta users and me. For example, I just found a bug in the Hotstrings list window (when double-clicking an entry). Wait at least for the next release v10.0.5 :-)