Options
"Add Active..." folder from QAPconnect file manager.
- "Add Active..." folder from QAPconnect file manager.
-
"Add Active..." folder from QAPconnect file manager.
kunkel321 > 2021-04-25 15:24
Hi Jean,
I use xyplorer as my default filemanager (via the QAPconnect module). Unfortunately the QAP menu item "Add Active..." for adding a folder does not seem to work from there. Though it does work as expected if used from inside the default Windows File Manager. Also, QAP does 'open' folders with xyplorer just fine. It is only the Add Active... that doesn't work. Please consider adding this feature--if it is even possible. -thanks in advance. -Steve
p.s. I'm not sure if it's relevant, but I use the portable versions of QAP and xyplorer. -
RE: "Add Active..." folder from QAPconnect file manager.
Jean Lalonde > 2021-04-25 15:55
Hi,
Unfortunately, QAP features requiring to detect the current folder in QAPconnect custom file managers are not supported currently. This would require to code specific code for each file managers. At this time, these features are only supported with Windows Explorer, Total Commander, Directory Opus and in Open/Save As dialog boxes.
Jean -
RE: "Add Active..." folder from QAPconnect file manager.
kunkel321 > 2021-04-25 17:27
Bummer. Okay, good to know. Thanks for the reply.
I went ahead and made a hack -- LOL
In xyplorer, if you click the address bar, it automatically selects the path. From there, press alt+shift+a.
I tried to run this from a snippet, but could not, so folks might need to have a copy of Autohotkey.exe to use it...
#NoEnv ; For security
#SingleInstance force ; If it gets restarted, kill and usurp the old process in RAM.
#Persistent ; Keep on keeping on.
SetTitleMatchMode, 2 ;
#ifWinActive, XYplorer
+!a::
send ^c
send !+q ;I set this hotkey in QAP prefs
WinWaitActive, Customize - Quick Access Popup
send ^n ;This is QAP's default hotkey
WinWaitActive, Add Favorite Type
send f
sleep 200 ;wait .2 seconds for the 'f' radio button to activate
send {Enter}
WinWaitActive, Add Favorite: Folder
RegExMatch(Clipboard, "([^\\]+)\.\w{1,4}$|([^\\]+)$", fname)
;MsgBox, % fname
send %fname%
send {Tab}
send ^v
send !a
return
#ifWinActive -
RE: "Add Active..." folder from QAPconnect file manager.
Jean Lalonde > 2021-04-26 17:11
Hi Steve,
Thanks for posting this AHK script. You are right, Macro Snippets could not do these actions. AutoHotkey is required.
User of QAP in other language than English will have to adapt some lines (especially windows title for the WinWaitActive commands and some keyboard shortcuts) but the core is there.
Also, the line "Send !+q ;I set this hotkey in QAP prefs" could be replaced by this code who will work regardless of user's hotkey config:
run, "C:\Program Files\Quick Access Popup\QAPmessenger.exe" ShowMenuLaunch
Jean
PS: I'll move this thread to the Support section. Other xyplorer users could find it there. -
RE: "Add Active..." folder from QAPconnect file manager.
kunkel321 > 2021-04-27 11:17
Thanks for the cool tip about QAPmessenger!
Strictly-speaking, "ShowMenuLaunch" does not work for this. This appears to launch my main custom popup. (My QAP). What needs to be opened there is the Customize window. It actually took me a while to figure out how to assign a hotkey to open that dialog. I did it by going to its menu item, and adding the hotkey to the menu item.
I did also see this https://www.quickaccesspopup.com/can-i-a...r-a-batch/
This method would negate the need for the regex pattern, and several of the WinWaitActive commands. (By the way, I didn't write that regex pattern, I found it on the AHK forums) :- } I'll post an updated version here shortly, that uses this command line option.
FYI the original version of the script I posted should probably have a short sleep after pressing 'f' and before Enter. I'll add it in the above post. -
RE: "Add Active..." folder from QAPconnect file manager.
Jean Lalonde > 2021-04-28 12:28
Yes, I was wrong in my previous message. Sorry about that. Thanks for the update, Steve. -
RE: "Add Active..." folder from QAPconnect file manager.
kunkel321 > 2021-04-28 19:23
Hey Jean,
With your QAPmessenger AddFile switch, is it supposed to open the "Add Favorite Document" dialog?? For me, it only opens the Add Favorite Folder dialog... Perhaps mine is behaving differently because I'm using a non-supported file manager(?) -
RE: "Add Active..." folder from QAPconnect file manager.
Jean Lalonde > 2021-04-28 20:37
Note sure in what context you are using this command? The AddFile parameter must be followed by the path of the file to add, for example:
"C:\Program Files\Quick Access Popup\QAPmessenger.exe" AddFile "C:\Folder\FilePath.ext"
When used from a Windows Explorer context menu of a document file, this command is executed with the path of the selected file added to the command. -
RE: "Add Active..." folder from QAPconnect file manager.
kunkel321 > 2021-04-29 08:12
Sorry, yes, I think I am using this incorrectly... I have it in an AutoHotkey script as:
Code:Run, "C:\PortableApps\quickaccesspopup\QAPmessenger.exe" AddFile clipboard
I don't think it's expanding the clipboard contents as expected though.
I tried it just now with:
Code:Run, "C:\PortableApps\quickaccesspopup\QAPmessenger.exe" AddFile "C:\Folder\actualfile.txt"
and it does work as expected.
When I was testing, I kept getting this error:
---------------------------
Sorry, we can't detect the current folder in this type of window.
Do you want to add a favorite folder manually now?
---------------------------
Yes No
---------------------------
It didn't even occur to me that the type of file manager will be completely irrelevant for this command line tool. I think maybe the error is caused from: because the file path is not expanding from the clipboard variable, QAPmessenger tries to "capture" it from the AHK editor that I'm using. Obviously it can't, so then I get the error message.
I will experiment more later. -
RE: "Add Active..." folder from QAPconnect file manager.
Jean Lalonde > 2021-04-29 08:22
To use the clipboard in this type of AHK commands, enclose it with %:
Run, "C:\PortableApps\quickaccesspopup\QAPmessenger.exe" AddFile %clipboard% -
RE: "Add Active..." folder from QAPconnect file manager.
kunkel321 > 2021-04-29 11:49
Ah yes -- Of course!
Thanks Jean.
Here is a more versatile (though also more complicated) version of the above script. If you click on a file or folder in xyplorer and "copy" it, it appears that the path is captured in addition to the actual item. (Though I don't recall it this is a default behavior of xy.) So an xy user can just click on an item in the list, then activate the script.
Code:#NoEnv ; For security
#SingleInstance force ; It it gets restarted, kill and usurp the old process in RAM.
#Persistent ; Keep on keeping on.
SetTitleMatchMode, 2
#IfWinActive, XYplorer
+!a::
Send, ^c ;ctrl+c (copy selected to clipboard)
Sleep, 100
RegExMatch(Clipboard, ".:\\.+\\", vPath)
if (!vPath) ; This means the regex didn't find the pattern.
{
MsgBox no path on clipboard. Stopping.
Return
}
RegExMatch(Clipboard, "\w+\.[A-z0-9]+$", vExt)
if (!vExt) ; This means that the above check passed, but there is not file at end of path.
{
vAdd := "AddFolder"
}
Else
{
vAdd := "AddFile"
}
;MsgBox % "vPath is:`t`t" vPath "`nvExt is:`t`t" vExt "`nvAdd is:`t`t" vAdd "`n`nClipboard is:`t" clipboard
;Run, "C:\PortableApps\quickaccesspopup\QAPmessenger.exe" %vAdd%Xpress "%Clipboard%" ; Xpress skips all dialogs.
Run, "C:\PortableApps\quickaccesspopup\QAPmessenger.exe" %vAdd% "%Clipboard%"
Return
#IfWinActive
EDIT: Just now added quotes around %clipboard%. (See below posts).
I also want to point out that the regexes in the above script aren't used by QAPmessenger. They are only used by the Autohotkey script to "direct traffic" in the script. Also, note that I have a portable version of Quick Access Popup in a custom location. Other users should have the "Run, "C:\......" part pointing to the correct location for their installation. -
RE: "Add Active..." folder from QAPconnect file manager.
Jean Lalonde > 2021-04-29 13:11
And enclose it with double-quotes if it can contain spaces:
"%clipboard%" -
RE: "Add Active..." folder from QAPconnect file manager.
kunkel321 > 2021-04-29 13:48
(2021-04-29 13:11)Jean Lalonde Wrote: And enclose it with double-quotes if it can contain spaces:
"%clipboard%"
Ha ha! I ran into this exact problem (with a space in the filename breaking it). I came to post about the problem, but you had already posted the solution -- Excellent. :- }
I will update the above script. -
RE: "Add Active..." folder from QAPconnect file manager.
Horst > 2021-04-30 08:04
(2021-04-29 13:48)kunkel321 Wrote:
To make this script more useful for others(2021-04-29 13:11)Jean Lalonde Wrote: And enclose it with double-quotes if it can contain spaces:
"%clipboard%"
Ha ha! I ran into this exact problem (with a space in the filename breaking it). I came to post about the problem, but you had already posted the solution -- Excellent. :- }
I will update the above script.
you should define a variable which pointa to QAPmessenger and later use this to start the tool.
Its a general advice to start scripts with a block of definitions for files, pathnames and switches.
This makes it universal and easy to change for you and others. -
RE: "Add Active..." folder from QAPconnect file manager.
kunkel321 > 2021-04-30 09:47
@Horst: Yes, good idea. I was also thinking that the "Xpress" part could be a variable, which could be defined at the top. Question though: This top block of definitions would go INSIDE the #IfWinActive part, correct?
Also, I think I've seen scripts that define the hotkey at the top, then use a "Hotkey" command further down. I've never tried to do one of those, but I'll check it out.
EDIT: As I think more about the 'Hotkey' thing, maybe this would not be needed... I suspect that the %path% and %express% would need to be defined directly below the hotkey:: any way... So it would already be in that top block of definitions... -
RE: "Add Active..." folder from QAPconnect file manager.
kunkel321 > 2021-04-30 11:38
Okay here we go. I changed the hotkey to Alt+F1. There is a nice little function I found on the AutoHotkey forums--not too complicated. Replaces what was on your clipboard. I think that maybe the Windows default is to capture an item's path when you copy the item from a file manager(?) Or maybe it's a default function for any AHK script. IDK. If tried removing the #IfWinActive, XYplorer part, and it worked in Windows File Explorer, Directory Opus, and Total Commander.
I also noticed that if you use the QAPmessenger switch, it doesn't seem to matter whether you use the 'folder' one or the 'file' one. Qm will detect what it is and apply the correct settings. It also will detect if the item is an application (.exe file).
Code:SetTitleMatchMode, 2 ; This line goes in the autoexecute header of the script.
#IfWinActive, XYplorer
!F1:: ; Trigger is Alt+F1
;#### Next two lines are options for script #########
QAPpath := "C:\PortableApps\quickaccesspopup" ; no slash at end of path
ShowDialogs := 1 ; 1 shows QAP dialogs, 0 skips them.
;#####################################################
selected := getSelected() ; calls function that is at the bottom
RegExMatch(selected, ".:\\.+\\", vPath)
if (!vPath) ; This means the regex didn't find the pattern.
{
MsgBox no path found. Stopping script.
Return
}
if ShowDialogs = 1
Switch := "AddFile" ; If it's a folder, QAP will use Folder settings.
else
Switch := "AddFileXpress" ; Skips dialogs and works tranparently.
if (!QAPpath) ; If no path is entered, use this default.
QAPpath := "C:\Program Files\Quick Access Popup"
Run, "%QAPpath%\QAPmessenger.exe" %Switch% "%selected%"
Return
; function from Masonjar on ahk forum
getSelected(){
cO:=clipboardAll
clipboard:=
send ^c
clipWait
selected:=clipboard
clipboard:=cO
return selected
}
#IfWinActive -
RE: "Add Active..." folder from QAPconnect file manager.
kunkel321 > 2022-12-14 17:11
In case there are any XYplorer users here: Here is a newer version of this AHK script for adding Favorite Folders. This one has a cool improvement, but the improvement also makes it somewhat kludgy.
Scenario: In my main QAP menu, I mostly like to group my folders. When I add a new folder, I want it to get inserted at the end of this group. At the bottom of the folders, I have a separator (------------------). So right before that separator, I put a uniquely-named Text Separator (see screenshot at bottom). After adding the separator, Edit it, and hide it.
Now notice that Jean has an option to insert a new Fave Folder before a particular item (Edit Favorite: Folder > Menu Options tab > Insert the favorite before this item). Even though the text separator is hidden, you can still use it as a marker for placing new favoriates before.
The code below is kludgy because it uses simulated key presses to navigate to the droplist where the hidden text separator is chosen. I named my text separator "z-bottom-of-folders". Note that this is the only menu item I have that starts with a "z". As such, simulating the z keypress scrolls the list right to the item. If your text separator starts with a different letter, define that in the line of code that looks like PlaceBefore := "z" If the variable %PlaceBefore% is blank, the simulated key presses are skipped. Or, if %ShowDialogs% is set to 0, then the dialogs are skipped altogether, and the new Favorite Folder will be placed at that very end of your QAP menu.
Also, if folks like syntax highlighting... https://pastebin.com/gfVh4acw
Code:;############## SAVE FAVE FOLDER XY > QAP ###############
#IfWinActive, XYplorer
!F1:: ; Trigger is Alt+F1
;MsgBox yes, you pressed the hotkey.
;--- Next two lines are options for script ----
QAPpath := "C:\Program Files\Quick Access Popup" ;no slash\ at end of path
ShowDialogs := 1 ;1 shows QAP dialogs, 0 skips them.
PlaceBefore := "z" ;In QAP > Add Folder > Menu Options > Add before this... list, go to this item. Blank means don't use this feature.
;----------------------------------------------
selected := getSelected() ; calls function that is at the bottom
RegExMatch(selected, ".:\\.+\\", vPath)
if (!vPath) ; This means the regex didn't find the pattern.
{
MsgBox no path found. Stopping script.
Return
}
if ShowDialogs = 1
Switch := "AddFile" ; If it's a folder, QAP will use Folder settings.
else
Switch := "AddFileXpress" ; Skips dialogs and works tranparently.
if (!QAPpath) ; If no path is entered, use this default.
QAPpath := "C:\Program Files\Quick Access Popup"
Run, "%QAPpath%\QAPmessenger.exe" %Switch% "%selected%"
ifequal, ShowDialogs, 1
{
; MsgBox, showDialogs = |%showDialogs%| `n`n PlaceBefore = |%placeBefore%|
IfNotEqual, PlaceBefore,
{
WinWaitActive, Add Favorite
Send, {Tab 8}
Send, {Right}
Send, {Tab 4}
Send, %PlaceBefore%
Send, !a
}
}
Return
; function from Masonjar on ahk forum
getSelected(){
cO:=clipboardAll
clipboard:=
send !c
clipWait
selected:=clipboard
clipboard:=cO
return selected
}
#IfWinActive
My setup with the hidden Text Separator:
![[Image: 0tW26Rm.png]](https://i.imgur.com/0tW26Rm.png)
-
RE: "Add Active..." folder from QAPconnect file manager.
kunkel321 > 2022-12-24 12:32
Okay, I did have an AHK question posted, but got help with it. see here:
https://www.autohotkey.com/boards/viewto...6&t=112059
This version does the same thing as the code in the reply just above this one, however the code in this reply is a bit more elegant because it doesn't use as many key-press-simulations...
The code is below, and here it is with syntax highlighting...
https://pastebin.com/wGr7jHD9
As indicated in the previous post; there are essentially three options:
(1) If the variable "ShowDialogs" is set to 0, then the folder (which is selected in xyplorer) gets transparently added to the end of the QAP menu (default behavior of QAPmessanger AddFileXpress.)
(2) If the variable "ShowDialogs" is set to 1, but there is nothing defined in the "PlaceBefore" variable (i.e. it is blank), then QAP will open the AddFolder dialog and keep it open. (default behavior of QAPmessanger AddFile.)
(3) If ShowDialogs is set to 1, and PlaceBefore is not blank, then this script will tell QAP to add the new folder just before the menu item with whatever name is defined by PlaceBefore. (Please see previous screenshot of my setup with a disabled text separator named "z-bottom-of-folders".) The Add Folder dialog will close, but the main QAP Settings window will stay open.
Code:;############## SAVE FAVE FOLDER XY > QAP ###############
#IfWinActive, XYplorer
!F1:: ; Trigger is Alt+F1
;MsgBox yes, you pressed the hotkey.
;--- Next two lines are options for script ----
QAPpath := "C:\Program Files\Quick Access Popup" ; no slash/ at end of path
ShowDialogs := 1 ; 1 shows QAP dialogs, 0 skips them.
PlaceBefore := "z-bottom-of-folders" ; In QAP > Add Folder > Menu Options > Add before this... list, go to this item. Blank means don't use this feature.
;----------------------------------------------
selected := getSelected() ; calls function that is at the bottom
RegExMatch(selected, ".:\\.+\\", vPath)
if (!vPath) ; This means the regex didn't find the pattern.
{
MsgBox no path found. Stopping script.
Return
}
if ShowDialogs = 1
Switch := "AddFile" ; If it's a folder, QAP will use Folder settings.
else
Switch := "AddFileXpress" ; Skips dialogs and works tranparently.
if (!QAPpath) ; If no path is entered, use this default.
QAPpath := "C:\Program Files\Quick Access Popup"
Run, "%QAPpath%\QAPmessenger.exe" %Switch% "%selected%"
If (ShowDialogs = 1) AND (PlaceBefore != "")
{
WinWaitActive, Add Favorite
Control, TabRight,, SysTabControl321, ahk_class JeanLalonde.ca
sleep, 100
Control, ChooseString, %PlaceBefore%, ComboBox2, A
Send, !a
}
Return
; function from Masonjar on ahk forum
getSelected(){
cO:=clipboardAll
clipboard:=
send !c
clipWait
selected:=clipboard
clipboard:=cO
return selected
}
#IfWinActive